有关流水号中间部分删除后新生成流水号的问题
MSSQL数据库

单据的流水号为：ZZ201404-0001、ZZ201404-0002、ZZ201404-0003、ZZ201404-0004、ZZ201404-0005
这个方式生成。

以前的流水号生成都是查到最大值后在后面加1来处理，哪怕中间有单据被删除，比如说ZZ201404-0003这单给删除了。
这样子0003这个流水以后永远都不会再次生成

现在客户有提出是否能生成新单，流水号为已删除了的流水号上的一个，
请问这种情况怎么查询啊？

如何查询流水号中间段已被删除的号段呢？
------解决方案--------------------

--这个情况之前论坛上有个经典的问题，叫找出第一个不连续的ID（意思是这个，记不清了）

--你自己搜搜看，跟你这个问题差不多

--不连续的两个ID之间肯定是有“空隙”的，你只能按照某个规律，找到断层的临界点（上临界或者下临界），不停的加1或者-1，

--重用之后继续按照这个规律找



create table ZZ

(

	id varchar(20)

)



insert into ZZ 



select 'ZZ201404-0001'

union

select 'ZZ201404-0002'

union

select 'ZZ201404-0004'

union

select 'ZZ201404-0005'

union

select 'ZZ201404-0006'

union

select 'ZZ201404-0008'

union

select 'ZZ201404-0009'



select * from ZZ



select top 1  rowid,id

from (

select ROW_NUMBER() over(order by id) as rowid,id

from ZZ)  as a 

where rowid<>substring(id,10,4)

order by id ASC



--输出

ZZ201404-0004



--证明从这个ID前面有“空隙”，那么你重用ID的话，对这个ID减1

--主要是这个思路，根据你实际情况修改

------解决方案--------------------

给了例子，自己参考写



--1．融合了补号处理的流水号编号处理

--下面是使用补号法生成流水编号的用户定义函数，生成的编号总长度为8位，以BH开头，其余6位为流水号。



--得到新编号的函数

CREATE FUNCTION f_NextBH()

RETURNS char(8)

AS

BEGIN

	DECLARE @r char(8)

	

	SELECT @r='BH'+RIGHT(1000001+MIN(BH),6)

	FROM(

		SELECT BH=RIGHT(BH,6) FROM tb WITH(XLOCK,PAGLOCK)

		UNION ALL SELECT 0

	)a WHERE NOT EXISTS(

		SELECT * FROM tb  WITH(XLOCK,PAGLOCK)

		WHERE BH='BH'+RIGHT(1000001+a.BH,6))

	RETURN(@r)

END

GO



--在表中应用函数

CREATE TABLE tb(

BH char(8) PRIMARY KEY DEFAULT dbo.f_NextBH(),

col int)

GO





/*==================================================*/







--2．融合了补号处理的日期编号处理

--下面是使用补号法生成日期编号的用户定义函数，生成的编号总长度为12，前6位为日期信息，格式为YYMMDD，后6位为流水号。



--创建得到当前日期的视图

CREATE VIEW v_GetDate

AS

SELECT dt=CONVERT(CHAR(6),GETDATE(),12)

GO



--得到新编号的函数

CREATE FUNCTION f_NextBH()

RETURNS char(12)

AS

BEGIN

	DECLARE @dt CHAR(6),@r char(12)

	SELECT @dt=dt FROM v_GetDate



	SELECT @r=@dt+RIGHT(1000001+MIN(BH),6)

	FROM(

		SELECT BH=RIGHT(BH,6) FROM tb WITH(XLOCK,PAGLOCK)

		WHERE BH like @dt+'%'

		UNION ALL SELECT 0

	)a WHERE NOT EXISTS(

		SELECT * FROM tb  WITH(XLOCK,PAGLOCK)

		WHERE BH like @dt+'%'

			AND BH=@dt+RIGHT(1000001+a.BH,6))

	RETURN(@r)

END

GO



--在表中应用函数

CREATE TABLE tb(

BH char(12) PRIMARY KEY DEFAULT dbo.f_NextBH(),

col int)