Win7开机启动批处理
我有一个UDP服务端和一个客户端程序，我想用批处理文件启动这两个程序，同时给客户端程序做个延时，批处理文件UDP.bat内容如下：

@ECHO OFF
TITLE STARTING WINDOWS
ECHO ************
ECHO 系统正在启动
ECHO ************
ECHO.
ECHO.
CALL LAST.BAT
>LAST.BAT ECHO ECHO 上次启动时间：
>>LAST.BAT ECHO ECHO.
>>LAST.BAT ECHO ECHO %TIME%
>>LAST.BAT ECHO ECHO %DATE%
ECHO STARTING Servers...
start "" "D:\Bin\Servers.exe"
ping -n 10 127.1>nul
ECHO STARTING Client...
start "" "D:\Client.exe"
EXIT

现在UDP.bat文件在Servers.exe目录下，没有问题！我想让这2个程序开机启动，所以将UDP.bat文件添copy到启动项中，结果Servers.exe启动读取配置文件失败！
这个问题该怎么解决？？？
------解决方案--------------------
为什么要将 UDP.BAT 文件复制到启动项里呢？给 Servers.exe 目录下的 UDP.BAT 创建个快捷方式，在启动项里使用这个快捷方式吧；或者，试试 start "" /D"D:\BIN" "D:\BIN\Servers.exe" 吧。
------解决方案--------------------

引用:

为什么要将 UDP.BAT 文件复制到启动项里呢？给 Servers.exe 目录下的 UDP.BAT 创建个快捷方式，在启动项里使用这个快捷方式吧；或者，试试 start "" /D"D:\BIN" "D:\BIN\Servers.exe" 吧。

+1

估计Servers.exe取的是当前工作目录，而不是Servers.exe本身所在目录。
------解决方案--------------------
@ECHO OFF
TITLE STARTING WINDOWS
ECHO ************
ECHO 系统正在启动
ECHO ************
ECHO.
ECHO.
cd /d "D:\Bin\"
CALL LAST.BAT
>LAST.BAT ECHO ECHO 上次启动时间：
>>LAST.BAT ECHO ECHO.
>>LAST.BAT ECHO ECHO %TIME%
>>LAST.BAT ECHO ECHO %DATE%
ECHO STARTING Servers...
start "" "D:\Bin\Servers.exe"
ping -n 10 127.1>nul
ECHO STARTING Client...
start "" "D:\Client.exe"
EXIT