/*
标题：简单数据拆分(version 2.0)
作者：爱新觉罗.毓华(十八年风雨,守得冰山雪莲花开)
时间：2010-05-07
地点：重庆航天职业学院
描述：

有表tb, 如下:
id          value
----------- -----------
1           aa,bb
2           aaa,bbb,ccc
欲按id,分拆value列, 分拆后结果如下:
id          value
----------- --------
1           aa
1           bb
2           aaa
2           bbb
2           ccc
*/

--1. 旧的解决方法(sql server 2000)

create table tb(id int,value varchar(30))
insert into tb values(1,'aa,bb')
insert into tb values(2,'aaa,bbb,ccc')
go

--方法1.使用临时表完成
SELECT TOP 8000 id = IDENTITY(int, 1, 1) INTO # FROM syscolumns a, syscolumns b 

SELECT A.id, value = SUBSTRING(A.[value], B.id, CHARINDEX(',', A.[value] + ',', B.id) - B.id)
FROM tb A, # B
WHERE SUBSTRING(',' + A.[value], B.id, 1) = ','

DROP TABLE #

--方法2.如果数据量小，可不使用临时表
select a.id , value = substring(a.value , b.number , charindex(',' , a.value + ',' , b.number) - b.number) 
from tb a join master..spt_values  b 
on b.type='p' and b.number between 1 and len(a.value)
where substring(',' + a.value , b.number , 1) = ','

--2. 新的解决方法(sql server 2005)
create table tb(id int,value varchar(30))
insert into tb values(1,'aa,bb')
insert into tb values(2,'aaa,bbb,ccc')
go

--方法1.使用xml完成
SELECT A.id, B.value FROM
(
  SELECT id, [value] = CONVERT(xml,'<root><v>' + REPLACE([value], ',', '</v><v>') + '</v></root>') FROM tb
) A OUTER APPLY
(
  SELECT value = N.v.value('.', 'varchar(100)') FROM A.[value].nodes('/root/v') N(v)
) B

--方法2.使用CTE完成
;with tt as 
(select id,[value]=cast(left([value],charindex(',',[value]+',')-1) as nvarchar(100)),Split=cast(stuff([value]+',',1,charindex(',',[value]+','),'') as nvarchar(100)) from tb
union all
select id,[value]=cast(left(Split,charindex(',',Split)-1) as nvarchar(100)),Split= cast(stuff(Split,1,charindex(',',Split),'') as nvarchar(100)) from tt where split>''
)
select id,[value] from tt order by id option (MAXRECURSION 0)


DROP TABLE tb

/*
id          value
----------- ------------------------------
1           aa
1           bb
2           aaa
2           bbb
2           ccc

(5 行受影响)
*/

------解决方案--------------------

经常用可以写一个函数.字符长度长时用函数也是一个比较好解决方法

SQL code
--> --> (Roy)生成測試數據
 
if not object_id('Tab') is null
    drop table Tab
Go
Create table Tab([a] int,[b] nvarchar(1000))
Insert Tab
select 1,N'1,2,3,1,4,5,6,7,7' union all
select 1,N'2,3' union all
select 2,N'1,2' union all
select 2,N'2,3' union all
select 3,N'1,2' union all
select 3,N'2,3'
Go
if OBJECT_ID('fn_split','FN') is not null
    drop function fn_split
go
Create function fn_split(@a int)
returns nvarchar(1000)
as
begin
    declare @s nvarchar(1000),@s2 nvarchar(1000),@i int,@split nvarchar(100)
    select @s=isnull(@s+',','')+b,@s2='' from Tab where a=@a
    select @i=charindex(',',@s),@s2=left(@s,@i),@s=replace(@s+',',@s2,''),@i=charindex(',',@s)
    while @i>0
    begin
        Select @split=left(@s,@i),@s2=@s2+@split,@s=replace(@s,@split,''),@i=charindex(',',@s)
    end
    return left(@s2,len(@s2)-1)
end
go

select [a],dbo.fn_split(a) as b from Tab group by [a]

/*
a    b
1    1,2,3,4,5,6,7
2    1,2,3
3    1,2,3
*/